Is it possible to run a .bat script (from the machines local c:\ drive) that
users can not close?
Or is hidden?

I use the 'start /min' command but students tend to close the window?

thanks

Try my freeware tool ShellExecute.exe, it will allow you to launch a hidden
window.

ShellExecute.exe /f:C:\MyFolder\MyBatch.cmd /r:hidden

http://www.optimumx.com/download/

Fabrussio wrote:

You can use a VBScript (.vbs) to launch a hidden batch file:


LaunchHiddenBatch.vbs

'--------------------8<----------------------
sTitle = "Batch launch"

Set oArgs = WScript.Arguments
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oShell = CreateObject("WScript.Shell")

If oArgs.Count <> 1 Then
   MsgBox "Error: You need to supply a file path " _
        & "as input parameter!", vbCritical + vbSystemModal, sTitle
   Wscript.Quit 1
End If

sFilePath = oArgs(0)

If Not oFSO.FileExists(sFilePath) Then
   MsgBox "Error: Batch file not found", vbCritical + vbSystemModal, sTitle
   Wscript.Quit 1
End If

' add quotes around the path in case of spaces
oShell.Run """" & sFilePath & """", 0, False

'--------------------8<----------------------

Shutdown Script
Install MSI remotely - problem
remote scripting how to
Retrieving an object's GUID as a string from Active Directory
ping subnet